سلام دوستان
کسی سورسی از یک نرم افزار داره که باهاش بشه حجم یک تصویر رو کاهش داد
خیلی ضروریه
هر کی داره کوتاهی نکنه
سلام.
پارامتر اول متد savejpg رو یه picturebox بفرست. پارامتر دوم یه آدرس که فایل jpg ذخیره بشه و پارامتر سوم کیفیت فایل. هر چه عدد پارامتر سوم رو کمتر کنی حجم عکست کمتر و طبیعتا عکست بی کیفیت تر میشه.
کد:
' ----==== API Declarations ====----
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(0 To 7) As Byte
End Type
Private Type GdiplusStartupInput
GdiplusVersion As Long
DebugEventCallback As Long
SuppressBackgroundThread As Long
SuppressExternalCodecs As Long
End Type
Private Type EncoderParameter
GUID As GUID
NumberOfValues As Long
type As Long
Value As Long
End Type
Private Type EncoderParameters
Count As Long
Parameter As EncoderParameter
End Type
Private Declare Function GdiplusStartup Lib "GDIPlus" ( _
token As Long, _
inputbuf As GdiplusStartupInput, _
Optional ByVal outputbuf As Long = 0) As Long
Private Declare Function GdiplusShutdown Lib "GDIPlus" ( _
ByVal token As Long) As Long
Private Declare Function GdipCreateBitmapFromHBITMAP Lib "GDIPlus" ( _
ByVal hbm As Long, _
ByVal hpal As Long, _
Bitmap As Long) As Long
Private Declare Function GdipDisposeImage Lib "GDIPlus" ( _
ByVal Image As Long) As Long
Private Declare Function GdipSaveImageToFile Lib "GDIPlus" ( _
ByVal Image As Long, _
ByVal filename As Long, _
clsidEncoder As GUID, _
encoderParams As Any) As Long
Private Declare Function CLSIDFromString Lib "ole32" ( _
ByVal str As Long, _
id As GUID) As Long
' ----==== SaveJPG ====----
Public Sub SaveJPG( _
ByVal pict As StdPicture, _
ByVal filename As String, _
Optional ByVal quality As Byte = 80)
Dim tSI As GdiplusStartupInput
Dim lRes As Long
Dim lGDIP As Long
Dim lBitmap As Long
' Initialize GDI+
tSI.GdiplusVersion = 1
lRes = GdiplusStartup(lGDIP, tSI)
If lRes = 0 Then
' Create the GDI+ bitmap
' from the image handle
lRes = GdipCreateBitmapFromHBITMAP(pict.Handle, 0, lBitmap)
If lRes = 0 Then
Dim tJpgEncoder As GUID
Dim tParams As EncoderParameters
' Initialize the encoder GUID
CLSIDFromString StrPtr("{557CF401-1A04-11D3-9A73-0000F81EF32E}"), _
tJpgEncoder
' Initialize the encoder parameters
tParams.Count = 1
With tParams.Parameter ' Quality
' Set the Quality GUID
CLSIDFromString StrPtr("{1D5BE4B5-FA4A-452D-9CDD-5DB35105E7EB}"), .GUID
.NumberOfValues = 1
.type = 4
.Value = VarPtr(quality)
End With
' Save the image
lRes = GdipSaveImageToFile( _
lBitmap, _
StrPtr(filename), _
tJpgEncoder, _
tParams)
' Destroy the bitmap
GdipDisposeImage lBitmap
End If
' Shutdown GDI+
GdiplusShutdown lGDIP
End If
If lRes Then
Err.Raise 5, , "Cannot save the image. GDI+ Error:" & lRes
End If
End Sub
سلام
آقا پیمان اگه تو پارامتر سوم عدد رو بیشتر کنیم کیفیت عکس بیشتر میشه؟
شرمنده من جواب دادم ولی اره بیشتر میشه و حجمش هم بیشتر میشه
(۱۲-خرداد-۱۳۹۰, ۲۳:۵۹:۳۰)sayberiya نوشته است: [ -> ]سلام
آقا پیمان اگه تو پارامتر سوم عدد رو بیشتر کنیم کیفیت عکس بیشتر میشه؟
سلام.
با افزایش و کاهش عدد کیفیت عکس بیشتر و کمتر میشه و به نسبت افزایش و کاهش کیفیت افزایش و کاهش حجم هم خواهیم داشت.
اما اگه یه عکس رو با quality پایین ذخیره کنی. بعد همون عکس بی کیفیت رو به تابع بدی و این بار بخوای با quality بالا ذخیره کنی کیفیت از دست دادش رو به دست نمیاره و نهایتا همون چیزی که در پیکچرباکس لود شده ذخیره میشه.
یعنی یه عکس که کیفیتش رو از دست داده با ارسال به این تابع و استفاده از quality بالا کیفیت از دست دادش رو به دست نمیاره. اما حجمش بیشتر از قبل میشه.